src/euler.lisp @ 829e38d1f825

(in-package :euler)

;;;; Utils --------------------------------------------------------------------
(defun digits (n)
  "Return how many digits `n` has in base 10."
  (values (truncate (1+ (log n 10)))))

(defun definitely-palindrome-p (n)
  "Return whether `n` is a palindrome (in base 10), the slow-but-sure way."
  (let ((s (format nil "~D" n)))
    (string= s (reverse s))))

(defun palindromep (n)
  "Return whether `n` is a palindrome (in base 10)."
  (assert (>= n 0) (n) "~A must be a non-negative integer" n)
  ;; All even-length base-10 palindromes are divisible by 11, so we can shortcut
  ;; the awful string comparison. E.g.:
  ;;
  ;;   abccba =
  ;;   100001 * a +
  ;;   010010 * b +
  ;;   001100 * c
  (cond
    ((zerop n) t)
    ((and (evenp (digits n))
          (not (dividesp n 11))) nil)
    (t (definitely-palindrome-p n))))

(defun sum (sequence)
  (iterate (for n :in-whatever sequence)
           (sum n)))


;;;; Problems -----------------------------------------------------------------
(defun problem-1 ()
  ;; If we list all the natural numbers below 10 that are multiples of 3 or 5,
  ;; we get 3, 5, 6 and 9. The sum of these multiples is 23.
  ;;
  ;; Find the sum of all the multiples of 3 or 5 below 1000.
  (iterate (for i :from 1 :below 1000)
           (when (or (dividesp i 3)
                     (dividesp i 5))
             (sum i))))

(defun problem-2 ()
  ;; Each new term in the Fibonacci sequence is generated by adding the previous
  ;; two terms. By starting with 1 and 2, the first 10 terms will be:
  ;;
  ;;     1, 2, 3, 5, 8, 13, 21, 34, 55, 89, ...
  ;;
  ;; By considering the terms in the Fibonacci sequence whose values do not
  ;; exceed four million, find the sum of the even-valued terms.
  (iterate (with a = 0)
           (with b = 1)
           (while (<= b 4000000))
           (when (evenp b)
             (sum b))
           (psetf a b
                  b (+ a b))))

(defun problem-3 ()
  ;; The prime factors of 13195 are 5, 7, 13 and 29.
  ;;
  ;; What is the largest prime factor of the number 600851475143 ?
  (apply #'max (prime-factorization 600851475143)))

(defun problem-4 ()
  ;; A palindromic number reads the same both ways. The largest palindrome made
  ;; from the product of two 2-digit numbers is 9009 = 91 × 99.
  ;;
  ;; Find the largest palindrome made from the product of two 3-digit numbers.
  (iterate (for-nested ((i :from 0 :to 999)
                        (j :from 0 :to 999)))
           (for product = (* i j))
           (when (palindromep product)
             (maximize product))))

(defun problem-5 ()
  ;; 2520 is the smallest number that can be divided by each of the numbers from
  ;; 1 to 10 without any remainder.
  ;;
  ;; What is the smallest positive number that is evenly divisible by all of the
  ;; numbers from 1 to 20?
  (iterate
    ;; all numbers are divisible by 1 and we can skip checking everything <= 10
    ;; because:
    ;;
    ;; anything divisible by 12 is automatically divisible by 2
    ;; anything divisible by 12 is automatically divisible by 3
    ;; anything divisible by 12 is automatically divisible by 4
    ;; anything divisible by 15 is automatically divisible by 5
    ;; anything divisible by 12 is automatically divisible by 6
    ;; anything divisible by 14 is automatically divisible by 7
    ;; anything divisible by 16 is automatically divisible by 8
    ;; anything divisible by 18 is automatically divisible by 9
    ;; anything divisible by 20 is automatically divisible by 10
    (with divisors = (range 11 21))
    (for i :from 20 :by 20) ; it must be divisible by 20
    (finding i :such-that (every (lambda (n) (dividesp i n))
                                 divisors))))

(defun problem-6 ()
  ;; The sum of the squares of the first ten natural numbers is,
  ;;   1² + 2² + ... + 10² = 385
  ;;
  ;; The square of the sum of the first ten natural numbers is,
  ;;   (1 + 2 + ... + 10)² = 55² = 3025
  ;;
  ;; Hence the difference between the sum of the squares of the first ten
  ;; natural numbers and the square of the sum is 3025 − 385 = 2640.
  ;;
  ;; Find the difference between the sum of the squares of the first one hundred
  ;; natural numbers and the square of the sum.
  (flet ((sum-of-squares (to)
           (sum (range 1 (1+ to) :key #'square)))
         (square-of-sum (to)
           (square (sum (range 1 (1+ to))))))
    (abs (- (sum-of-squares 100) ; apparently it wants the absolute value
            (square-of-sum 100)))))

(defun problem-7 ()
  ;; By listing the first six prime numbers: 2, 3, 5, 7, 11, and 13, we can see
  ;; that the 6th prime is 13.
  ;;
  ;; What is the 10 001st prime number?
  (nth-prime 10001))

(defun problem-8 ()
  ;; The four adjacent digits in the 1000-digit number that have the greatest
  ;; product are 9 × 9 × 8 × 9 = 5832.
  ;;
  ;; Find the thirteen adjacent digits in the 1000-digit number that have the
  ;; greatest product. What is the value of this product?
  (let ((digits (map 'list #'digit-char-p
                     "7316717653133062491922511967442657474235534919493496983520312774506326239578318016984801869478851843858615607891129494954595017379583319528532088055111254069874715852386305071569329096329522744304355766896648950445244523161731856403098711121722383113622298934233803081353362766142828064444866452387493035890729629049156044077239071381051585930796086670172427121883998797908792274921901699720888093776657273330010533678812202354218097512545405947522435258490771167055601360483958644670632441572215539753697817977846174064955149290862569321978468622482839722413756570560574902614079729686524145351004748216637048440319989000889524345065854122758866688116427171479924442928230863465674813919123162824586178664583591245665294765456828489128831426076900422421902267105562632111110937054421750694165896040807198403850962455444362981230987879927244284909188845801561660979191338754992005240636899125607176060588611646710940507754100225698315520005593572972571636269561882670428252483600823257530420752963450")))
    (iterate (for window :in (n-grams 13 digits))
             (maximize (apply #'* window)))))

(defun problem-9 ()
  ;; A Pythagorean triplet is a set of three natural numbers, a < b < c, for
  ;; which:
  ;;
  ;;   a² + b² = c²
  ;;
  ;; For example, 3² + 4² = 9 + 16 = 25 = 5².
  ;;
  ;; There exists exactly one Pythagorean triplet for which a + b + c = 1000.
  ;; Find the product abc.
  (flet ((pythagorean-triplet-p (a b c)
           (= (+ (square a) (square b))
              (square c))))
    ;; They must add up to 1000, so C can be at most 998.
    ;; A can be at most 999 - C (to leave 1 for B).
    (iterate (for c :from 998 :downto 1)
             (iterate (for a :from (- 999 c) :downto 1)
                      (for b = (- 1000 c a))
                      (when (pythagorean-triplet-p a b c)
                        (return-from problem-9 (* a b c)))))))

(defun problem-10 ()
  ;; The sum of the primes below 10 is 2 + 3 + 5 + 7 = 17.
  ;; Find the sum of all the primes below two million.
  (sum (primes-below 2000000)))


;;;; Tests --------------------------------------------------------------------
(def-suite :euler)
(in-suite :euler)

(test p1 (is (= 233168 (problem-1))))
(test p2 (is (= 4613732 (problem-2))))
(test p3 (is (= 6857 (problem-3))))
(test p4 (is (= 906609 (problem-4))))
(test p5 (is (= 232792560 (problem-5))))
(test p6 (is (= 25164150 (problem-6))))
(test p7 (is (= 104743 (problem-7))))
(test p8 (is (= 23514624000 (problem-8))))
(test p9 (is (= 31875000 (problem-9))))
(test p10 (is (= 142913828922 (problem-10))))


; (run! :euler)